如何打印大于屏幕显示范围的窗体
编号：QA001949
建立日期: 1999年11月2日 最后修改日期：1999年11月2日
所属类别：
eb:
有什么方法可以将整个窗体的内容打印出来，（窗体比屏幕显示范围大，屏幕不能全部显示窗体内容）？？谢谢！！！！！！！！
回答:
下面的内容摘自微软的Knowledge Base的文章：“Q230502 OWTO: Print a Form That is Too Large for the Screen or Page”。
SUMMARY
=======
You are attempting to print a form that is larger than the screen, or only partially displayed. The PrintForm method prints only the portion of the form that is displayed. You may also have a form that is too large to print on one page. This article demonstrates how to accomplish both of these tasks.
NOTE: Visual Basic 6.0 Online help states that PrintForm prints the entire form, whether or not the entire form is visible. This information is not correct.
MORE INFORMATION
================
In order to accomplish this task, the controls on the form must be placed in a PictureBox. What you will actually print is the bitmap that is contained in the PictureBox, instead of a screen capture of the form itself (which is what PrintForm does). Because the PictureBox's bitmap is stored in a device context in memory, we have access to the entire bitmap, regardless of what displays. Note that for the purposes of this article the height of the form is set to 11 inches. If another paper size is desired, like 8.5 x 14, set the sTall variable to an appropriate value, for example 14. Note also that these assignments are made in twips because this is the default scalemode for forms. If you change the scalemode, you will need to also change these values to match.
Print a Form that is Larger than the Screen
-------------------------------------------
1. Start a new Standard EXE project in Visual Basic. Form1 is created by default.
2. Add two PictureBoxes to Form1.
Avoid drawing the second PictureBox within the first. Doing so makes the second PictureBox a member of the first. One way to avoid this problem is to place the origin point of the second PictureBox to the left of the origin point of the first PictureBox.
3. Right-click Picture2 and choose Send to Back.
4. Add two labels to Picture1, leaving Picture2 empty.
5. Add the following code to the General Declarations section of Form1:
Private Const twipFactor = 1440
Private Const WM_PAINT = &HF
Private Const WM_PRINT = &H317
Private Const PRF_CLIENT = &H4& ' Draw the window's client area.
Private Const PRF_CHILDREN = &H10& ' Draw all visible child windows.
Private Const PRF_OWNED = &H20& ' Draw all owned windows.
Private Declare Function SendMessage Lib "user32" Alias _
"SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
Private Sub Form_Load()
Dim sWide As Single, sTall As Single
Dim rv As Long
Me.ScaleMode = vbTwips ' default
sWide = 8.5
stall = 11 ' or 14, etc.
Me.Width = twipFactor * sWide
Me.Height = twipFactor * stall
With Picture1
.Top = 0
.Left = 0
.Width = twipFactor * sWide
.Height = twipFactor * stall
End With
With Picture2
.Top = 0
.Left = 0
.Width = twipFactor * sWide
.Height = twipFactor * stall
End With
With Label1
.Caption = "Top"
.Left = Me.Width / 2
.Top = 0
End With
With Label2
.Caption = "Bottom"
.Top = (twipFactor * stall) - .Height * 2
.Left = Me.Width / 2
End With
Me.Visible = True
DoEvents
Picture1.SetFocus
Picture2.AutoRedraw = True
rv = SendMessage(Picture1.hwnd, WM_PAINT, Picture2.hDC, 0)
rv = SendMessage(Picture1.hwnd, WM_PRINT, Picture2.hDC, _
PRF_CHILDREN + PRF_CLIENT + PRF_OWNED)
Picture2.Picture = Picture2.Image
Picture2.AutoRedraw = False
Printer.Print ""
Printer.PaintPicture Picture2.Picture, 0, 0
Printer.EndDoc
End Sub
6. Run the project.
7. The "Top" and "Bottom" labels should appear in their respective positions regardless of whether or not the form is completely displayed.
Print a Form on More Than One Page
----------------------------------
If the form you are printing is too large to fit on a page, you can use the same approach as in the preceding example with a minor addition. The PaintPicture method has a number of optional parameters. The clipping region parameters can be used to grab a portion of the bitmap image and print it.
To accomplish this, locate the following code in the previous example:
Printer.Print ""
Printer.PaintPicture Picture2.Picture, 0, 0
Printer.EndDoc
Replace those three lines of code with the following:
Printer.Print ""
Printer.PaintPicture Picture2.Picture, 0, 0, , , _
0, 0, , Picture2.Height / 2
Printer.NewPage
Printer.PaintPicture Picture2.Picture, 0, 0, , , _
0, Picture2.Height / 2, , Picture2.Height / 2
Printer.EndDoc
For ease of illustration, this example merely divides the form in half. You can adjust the clipping region appropriately for you needs.
REFERENCES
==========
For additional information about printing forms, please see the following article in the Microsoft Knowledge Base:
Q178076 HOWTO: Use a PictureBox to Control Orientation Printing a Form
Visual Basic OnLine Help; search on: "PaintPicture"
|
此问题由李海回答。
| |
|
|
| |
|
|
